ASP 脚本源码

名称 描述
ENC( str ) 文字编码, 消除 HTML 标记的功能, 达到直接显示的目的
GetSqlString( str ) 将字符串转成 SQL 语句中的字符串格式, 堵住 SQL 注入漏洞
FillTD( str ) 将字符串显示到单元格中, 当为空时, 转成 <BR>, 避免内容为空的单元格边框不显示的情况
JavaString( str ) 将字符串转到 javascript 中的字符串格式, 直接输出到 javascript 脚本中
Rs2Js( recordset ) 将记录集转成 javascript 中的二维数组形式
To_Number( str, def ) 将字符串转为浮点数, 无法转换时, 用默认值
To_Currency( num ) 将数字转成两位小数形式, 纯小数时补足个位上的零

Enc

Function Enc( ByVal str )
  If IsNull(str) Then
    enc = str
  Else
    enc = server.htmlencode( CStr(str) )
  End If
End Function

JavaString

Function JavaString( ByVal str )

  Dim s

  If IsNull(str) Then
    s = ""
  Else
    s = CStr(str)
    s = Replace(s, "\", "\\")
    s = Replace(s, """", "\""")
    s = Replace(s, vbcrlf, "\n")
  End If

  javastring = """" & s & """"

End Function

FillTD

Function FillTD( ByVal str )

  FillTD = Enc( str )
  If IsNull(FillTD) Or Replace(FillTD," ","") = "" Then
    FillTD = "<BR>"
  End If
  FillTD = Replace(FillTD, vbCrLf, "<BR>")

End Function

GetSqlString

Function GetSqlString( ByVal str )
  Dim s
  If IsNull(str) Then
    s = ""
  Else
    s = CStr(str)
  End If

  GetSqlString = "'" & Replace(CStr(s),"'","''") & "'"
End Function

Rs2Js

Function Rs2Js( rs )
  Dim sone, sall
  Dim i

  sall = ""
  Do While Not rs.EOF
    sone = ""
    For i=0 To rs.fields.count-1
      If i>0 Then
        sone = sone & ","
      End If
      sone = sone & JavaString(rs.fields(i).value)
    Next
    If sall<>"" Then
      sall = sall & ","
    End If

    sall = sall & "[" & sone & "]" & vbcrlf
    rs.MoveNext
  Loop

  Rs2Js = replace(sall,"<","<""+""")

End Function

To_Number

Function To_Number( ByVal str, ByVal def )

  If Not IsEmpty(str) And IsNumeric(str) Then
    To_Number = CDbl(str)
  Else
    To_Number = def
  End If

End Function

To_Currency

Function To_Currency( ByVal num )

  Dim s
  s = FormatNumber(num)
  If Left(s,1) = "." Then
    s = "0" & s
  End If

  To_Currency = s

End Function